EventKG
SPARQL Endpoint
The EventKG SPARQL endpoint can be found here.Example Resources
Example Queries
- Most linked events in the Russian Wikipedia
PREFIX eventKG-s: <http://eventKG.l3s.uni-hannover.de/schema/>
PREFIX eventKG-g: <http://eventKG.l3s.uni-hannover.de/graph/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX sem: <http://semanticweb.cs.vu.nl/2009/11/sem/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX dbr: <http://dbpedia.org/resource/>
SELECT ?dbp ?links {
?event rdf:type sem:Event .
GRAPH eventKG-g:dbpedia_en { ?event owl:sameAs ?dbp . } .
{
SELECT ?event (SUM(?link_count) AS ?links) WHERE {
?relation rdf:type eventKG-s:Relation .
?relation rdf:object ?event .
GRAPH eventKG-g:wikipedia_ru { ?relation eventKG-s:links ?link_count . } .
} GROUP BY ?event
}
} ORDER BY DESC(?links)
LIMIT 8
- Sub-events of World War II that started between February 12 and February 28, 1941.
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX eventKG-s: <http://eventKG.l3s.uni-hannover.de/schema/>
PREFIX eventKG-g: <http://eventKG.l3s.uni-hannover.de/graph/>
PREFIX so: <http://schema.org/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX sem: <http://semanticweb.cs.vu.nl/2009/11/sem/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX dbr: <http://dbpedia.org/resource/>
SELECT ?startTime group_concat(DISTINCT(STR(?description));separator=',') (?sa AS ?event_resource)
WHERE {
?event owl:sameAs dbr:World_War_II .
?event sem:hasSubEvent* ?subEvent .
?subEvent sem:hasBeginTimeStamp ?startTime .
OPTIONAL {
GRAPH eventKG-g:wikipedia_en { ?subEvent dcterms:description ?description . } .
FILTER(LANGMATCHES(LANG(?description), "en")) .
}
OPTIONAL { GRAPH eventKG-g:dbpedia_en { ?subEvent owl:sameAs ?sa . } . } .
FILTER (?startTime >= "1941-02-12"^^xsd:date) .
FILTER (?startTime < "1941-02-28"^^xsd:date) .
FILTER(BOUND(?sa) || BOUND(?description)) .
}
GROUP BY ?startTime ?subEvent ?sa
ORDER BY ASC(?startTime)
startTime description event_resource 1941-02-12 WWII: Erwin Rommel arrives in Tripoli. 1941-02-14 Admiral Kichisaburō Nomura begins his duties as Japanese Ambassador to the United States. 1941-02-17 The Battle of Trebeshina or the Battle of Mal Trebeshinë, was a series of engagements fought between the Greek and Italian armies in south-eastern Albania during the Greco-Italian War. http://dbpedia.org/resource/Battle_of_Trebeshina 1941-02-19 Three Nights' Blitz over Swansea, South Wales: Over these 3 nights of intensive bombing, which lasted a total of 13 hours and 48 minutes, Swansea's town centre is almost completely obliterated by the 896 high explosive bombs employed by the Luftwaffe; 397 casualties and 230 deaths reported. 1941-02-22 Bombards Barawa, on the coast between Kismayo and Mogadishu. 1941-02-25 Operation Abstention was a code name given to a British invasion of the Italian island of Kastelorizo, off Turkey, during the Second World War, in late February 1941. http://dbpedia.org/resource/Operation_Abstention 1941-02-27 The Action of 27 February 1941 was a single ship action between a New Zealand cruiser and an Italian auxiliary cruiser. http://dbpedia.org/resource/Action_of_27_February_1941 1941-02-27 The New Zealand Division cruiser HMS Leander (1931) sinks Italian armed merchant raider Ramb I off the Maldives. - Locations of the Battle of Trafalgar
PREFIX eventKG-s: <http://eventKG.l3s.uni-hannover.de/schema/>
PREFIX eventKG-g: <http://eventKG.l3s.uni-hannover.de/graph/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX so: <http://schema.org/>
PREFIX sem: <http://semanticweb.cs.vu.nl/2009/11/sem/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX dbr: <http://dbpedia.org/resource/>
SELECT ?location
WHERE
{
?event rdf:type sem:Event .
?event owl:sameAs dbr:Battle_of_Trafalgar .
GRAPH eventKG-g:event_kg {?event sem:hasPlace ?loc} .
GRAPH eventKG-g:dbpedia_en { ?loc owl:sameAs ?location . }
}
- Start and end times of World War II
PREFIX eventKG-s: <http://eventKG.l3s.uni-hannover.de/schema/>
PREFIX sem: <http://semanticweb.cs.vu.nl/2009/11/sem/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX dbr: <http://dbpedia.org/resource/>
SELECT ?startTime ?endTime ?graph
WHERE
{
?event owl:sameAs dbr:World_War_II .
GRAPH ?graph { ?event sem:hasBeginTimeStamp ?startTime } .
GRAPH ?graph { ?event sem:hasEndTimeStamp ?endTime } .
}
startTime endTime graph 1939-01-01 1939-12-31 http://eventKG.l3s.uni-hannover.de/graph/yago 1939-09-01 1945-09-02 http://eventKG.l3s.uni-hannover.de/graph/wikidata 1939-09-01 1945-09-02 http://eventKG.l3s.uni-hannover.de/graph/event_kg